module metadata

import encoding.iconv

@[heap]
pub struct Frame {
	mut:
		size u64
		start u64
		end u64
		apic ?[]u8
		coded_size ?[]u64
		addition []u8
		encoding string
		text string
		name string
}

// Во врейме первый байт указывает кодировку 0 - ISO-8859-1 (Latin-1), 1 - UTF-16LE
@[inline]
fn (mut frame Frame) fill_frame(bytes []u8, start_position u64, idv3_version u8) {
	// Начало фрейма
	frame.start = start_position
	// Название фрейма
	frame.name = bytes[frame.start..frame.start + 4].bytestr()

	// Размер фрейма
	frame.size = if idv3_version == 3 { 
		get_size_v23(bytes[frame.start+4..frame.start+8]) 
	} else { 
		get_size_v24(bytes[frame.start+4..frame.start+8]) 
	}
	// Конец фрейма
	frame.end = frame.start + frame.size + 10

	// Содержимое фрейма
	frame.encoding = match bytes[frame.start+10] { 
		0 { "ISO-8859-1" }
		1 { "UTF-16LE" } 
		2 { "UTF-16BE" } 
		else { "UTF-8" }
	}

	if frame.name.to_lower() == "apic" {
		// Дополнительные байты с информацией (MIME)
		frame.addition = bytes[frame.start+10..frame.start+24]
		frame.apic = bytes[frame.start+24..frame.end]
	} else {
		// Выбор шага в записимости от версии
		stride := if idv3_version == 3 { 13 } else { 11 }
		frame.text = iconv.encoding_to_vstring(bytes[frame.start+u64(stride)..frame.end], frame.encoding) or { "" } 

		frame.addition = bytes[frame.start..frame.start + 10]
	}
}

// Кодируем длину фрейма с нужным сдвигом
@[inline]
pub fn (mut frame Frame) encode_size(idv3_version u8) []u64 {
	stride := if idv3_version == 3 { 
		[u64(24), u64(16), u64(8), u64(0xFF)] 
	} else { 
		[u64(21), u64(14), u64(7), u64(0x7F)] 
	}

	return [
		(frame.size >> stride[0]) & stride[3], 
		(frame.size >> stride[1]) & stride[3], 
		(frame.size >> stride[2]) & stride[3], 
		frame.size & stride[3]
	]
}